Reorganize files and add Mandelbrot shader

shaders/mandelbrot.frag

@@ -0,0 +1,60 @@
+#version 330 core
+
+out vec4 fragColor;
+
+uniform float u_time;
+uniform uint u_frame;
+uniform vec2 u_resolution;
+uniform vec2 u_mouse;
+
+// Source: https://github.com/kbinani/colormap-shaders/blob/master/shaders/glsl/MATLAB_jet.frag
+float colormap_red(float x) {
+  if (x < 0.7) {
+    return 4.0 * x - 1.5;
+  } else {
+    return -4.0 * x + 4.5;
+  }
+}
+
+float colormap_green(float x) {
+  if (x < 0.5) {
+    return 4.0 * x - 0.5;
+  } else {
+    return -4.0 * x + 3.5;
+  }
+}
+
+float colormap_blue(float x) {
+  if (x < 0.3) {
+    return 4.0 * x + 0.5;
+  } else {
+    return -4.0 * x + 2.5;
+  }
+}
+
+vec4 colormap(float x) {
+  float r = clamp(colormap_red(x), 0.0, 1.0);
+  float g = clamp(colormap_green(x), 0.0, 1.0);
+  float b = clamp(colormap_blue(x), 0.0, 1.0);
+  return vec4(r, g, b, 1.0);
+}
+
+// Mandelbrot
+vec2 f(vec2 z) {
+  vec2 c = gl_FragCoord.xy / u_resolution.xy * 2.6 - vec2(2.0, 1.3);
+  return vec2(z.x * z.x - z.y * z.y, 2 * z.x * z.y) + c;
+}
+
+void main() {
+  vec2 z = vec2(0.0);
+  int i = 0;
+  while (length(z) <= 4 && i < 1000) {
+    z = f(z);
+    i++;
+  }
+  if (i == 1000) {
+    fragColor = vec4(vec3(0.0), 1.0);
+  } else {
+    fragColor = colormap(smoothstep(0.0, 23.0, i));
+  }
+}

shaders/simplexnoise.frag

@@ -0,0 +1,86 @@
+#version 330 core
+
+out vec4 fragColor;
+
+uniform float u_time;
+uniform uint u_frame;
+uniform vec2 u_resolution;
+uniform vec2 u_mouse;
+
+// Some useful functions
+vec3 mod289(vec3 x) { return x - floor(x * (1.0 / 289.0)) * 289.0; }
+vec2 mod289(vec2 x) { return x - floor(x * (1.0 / 289.0)) * 289.0; }
+vec3 permute(vec3 x) { return mod289(((x * 34.0) + 1.0) * x); }
+
+//
+// Description : GLSL 2D simplex noise function
+//      Author : Ian McEwan, Ashima Arts
+//  Maintainer : ijm
+//     Lastmod : 20110822 (ijm)
+//     License :
+//  Copyright (C) 2011 Ashima Arts. All rights reserved.
+//  Distributed under the MIT License. See LICENSE file.
+//  https://github.com/ashima/webgl-noise
+//
+float snoise(vec2 v) {
+
+  // Precompute values for skewed triangular grid
+  const vec4 C = vec4(0.211324865405187,  // (3.0-sqrt(3.0))/6.0
+                      0.366025403784439,  // 0.5*(sqrt(3.0)-1.0)
+                      -0.577350269189626, // -1.0 + 2.0 * C.x
+                      0.024390243902439); // 1.0 / 41.0
+
+  // First corner (x0)
+  vec2 i = floor(v + dot(v, C.yy));
+  vec2 x0 = v - i + dot(i, C.xx);
+
+  // Other two corners (x1, x2)
+  vec2 i1 = vec2(0.0);
+  i1 = (x0.x > x0.y) ? vec2(1.0, 0.0) : vec2(0.0, 1.0);
+  vec2 x1 = x0.xy + C.xx - i1;
+  vec2 x2 = x0.xy + C.zz;
+
+  // Do some permutations to avoid
+  // truncation effects in permutation
+  i = mod289(i);
+  vec3 p =
+      permute(permute(i.y + vec3(0.0, i1.y, 1.0)) + i.x + vec3(0.0, i1.x, 1.0));
+
+  vec3 m = max(0.5 - vec3(dot(x0, x0), dot(x1, x1), dot(x2, x2)), 0.0);
+
+  m = m * m;
+  m = m * m;
+
+  // Gradients:
+  //  41 pts uniformly over a line, mapped onto a diamond
+  //  The ring size 17*17 = 289 is close to a multiple
+  //      of 41 (41*7 = 287)
+  vec3 x = 2.0 * fract(p * C.www) - 1.0;
+  vec3 h = abs(x) - 0.5;
+  vec3 ox = floor(x + 0.5);
+  vec3 a0 = x - ox;
+
+  // Normalise gradients implicitly by scaling m
+  // Approximation of: m *= inversesqrt(a0*a0 + h*h);
+  m *= 1.79284291400159 - 0.85373472095314 * (a0 * a0 + h * h);
+
+  // Compute final noise value at P
+  vec3 g = vec3(0.0);
+  g.x = a0.x * x0.x + h.x * x0.y;
+  g.yz = a0.yz * vec2(x1.x, x2.x) + h.yz * vec2(x1.y, x2.y);
+  return 130.0 * dot(m, g);
+}
+
+void main() {
+  vec2 st = gl_FragCoord.xy / u_resolution.xy;
+  st.x *= u_resolution.x / u_resolution.y;
+
+  vec3 color = vec3(0.0);
+
+  // Scale the space in order to see the function
+  st *= 10.0;
+
+  color = vec3(snoise(st) * .5 + .5);
+
+  fragColor = vec4(color, 1.0);
+}